InsertColumnExp proc
	LOCAL lvc:LV_COLUMN
	mov lvc.imask,LVCF_TEXT+LVCF_WIDTH
	mov lvc.pszText,offset Heading1
	.if langage != 40Ch
		mov lvc.pszText,offset Heading1A
	.endif
	mov lvc.lx,170
	invoke SendMessage,hList, LVM_INSERTCOLUMN,0,addr lvc
	or lvc.imask,LVCF_FMT
	mov lvc.fmt,LVCFMT_LEFT
	mov lvc.pszText,offset Heading3
	mov lvc.lx,114
	invoke SendMessage,hList, LVM_INSERTCOLUMN, 1 ,addr lvc
	ret		
InsertColumnExp endp



RemplirListViewExp proc uses edi row:DWORD, addrNomFonction:DWORD, addrNomDLL:DWORD
	LOCAL lvi:LV_ITEM
	LOCAL bufferListView[20]:BYTE
	
	mov lvi.imask,LVIF_TEXT+LVIF_PARAM
	push row				; pousse le numéro de la colonne sur la pile
	pop lvi.iItem			; récupère le numéro de la colonne dans la structure
	mov lvi.iSubItem,0		
	mov eax, addrNomFonction	;<----------------------------------------------------- Noms des Fonctions
	mov lvi.pszText,eax

	push row
	pop lvi.lParam
	invoke SendMessage,hList, LVM_INSERTITEM,0, addr lvi

	mov lvi.imask,LVIF_TEXT
	inc lvi.iSubItem
	mov eax, addrNomDLL	;<------------------------------------------------------ Noms des Dll	
	mov lvi.pszText,eax
	invoke SendMessage,hList,LVM_SETITEM, 0,addr lvi

	ret
RemplirListViewExp endp





RVAToFileMap PROC uses edi esi edx ecx pFileMap:DWORD,RVA:DWORD
	mov esi,pFileMap
	assume esi:ptr IMAGE_DOS_HEADER
	add esi,[esi].e_lfanew
	assume esi:ptr IMAGE_NT_HEADERS
	mov edi,RVA	; edi == RVA
	mov edx,esi
	add edx,sizeof IMAGE_NT_HEADERS
	mov cx,[esi].FileHeader.NumberOfSections
	movzx ecx,cx
	assume edx:ptr IMAGE_SECTION_HEADER
	.while ecx>0	; check all sections
		.if edi>=[edx].VirtualAddress
			mov eax,[edx].VirtualAddress
			add eax,[edx].SizeOfRawData
			.if edi<eax	; The address is in this section
				mov eax,[edx].VirtualAddress
				sub edi,eax	; edi == difference between the specified RVA and the section's RVA
				mov eax,[edx].PointerToRawData
				add eax,edi	; eax == file offset
				add eax,pFileMap
				ret
			.endif
		.endif
		add edx,sizeof IMAGE_SECTION_HEADER
		dec ecx
	.endw
	assume edx:nothing
	assume esi:nothing
	mov eax,edi
	ret
RVAToFileMap endp



ShowTheFunctionsExp proc uses esi ecx ebx pNTHdr:DWORD
	LOCAL temp[50]:BYTE
	LOCAL temp2[50]:BYTE
	LOCAL NumberOfNames:DWORD
	LOCAL Base:DWORD
	
	jmp data@4
	NoExportTable db "No export information in this file",0
	template db "%s",0
	data@4:


	mov edi,pNTHdr
	assume edi:ptr IMAGE_NT_HEADERS
	mov edi, [edi].OptionalHeader.DataDirectory.VirtualAddress
	invoke RVAToFileMap,pMapping,edi
	mov edi,eax
	assume edi:ptr IMAGE_EXPORT_DIRECTORY
	mov eax,[edi].NumberOfFunctions
	invoke RVAToFileMap, pMapping,[edi].nName
	push [edi].NumberOfNames
	pop NumberOfNames
	push [edi].nBase
	pop Base
	invoke RVAToFileMap,pMapping,[edi].AddressOfNames
	mov esi,eax
	invoke RVAToFileMap,pMapping,[edi].AddressOfNameOrdinals
	mov ebx,eax
	invoke RVAToFileMap,pMapping,[edi].AddressOfFunctions
	mov edi,eax
	.while NumberOfNames>0				
		invoke RVAToFileMap,pMapping,dword ptr [esi]
		mov dx,[ebx]
		movzx edx,dx
		mov ecx,edx
		add ecx,Base
		shl edx,2
		add edx,edi
		invoke wsprintf, addr temp,addr template,eax
		;invoke AppendText,hDlg,addr temp
		pushad
		  invoke lstrcpy, addr temp2, addr temp
		  invoke lstrlen, offset BufferFonction
		  mov ecx, eax
		  mov esi, offset BufferFonction
		  lea edi, temp
		  invoke lcase, edi
		  cmp byte ptr [BufferFonction], "*"
		  je entrer
		  repe cmpsb
		  jnz pasbonnefonction
		  entrer:
		  lea eax, temp2
		  invoke RemplirListViewExp,0, eax, offset Buffer	;************************************
		  ; BufferFonction contient le contenu du control d'édition
		  pasbonnefonction:
		popad
		dec NumberOfNames
		add esi,4
		add ebx,2
	.endw
	ret
ShowTheFunctionsExp endp



FindExports proc uses edi
	LOCAL seh		:SEH
	LOCAL tour		:DWORD
	LOCAL numDLL		:DWORD
	LOCAL numDll		:DWORD
	LOCAL NomFichierDLL[150]	:BYTE

	jmp data@3
		AntiSlash	db "\",0
		Kernel32	db "KERNEL32.dll",0	; -
		User32	db "USER32.dll",0	; -
		Shell32	db "SHELL32.dll",0	; -
		Gdi	db "GDI32.dll",0	; -
		olesvr	db "OLESVR32.dll",0	; -
		olecli	db "OLECLI32.dll",0	; -
		comdlg32	db "comdlg32.dll",0	; -
		advapi32	db "ADVAPI32.dll",0	; -
		comctl32	db "COMCTL32.dll",0	; -
		crtdll	db "CRTDLL.dll",0	; -
		version	db "VERSION.dll",0	; -
	data@3:

	invoke lstrcpy, addr NomFichierDLL, addr CheminFichier
	invoke lstrcat, addr NomFichierDLL, addr fichierDLL

	mov tour, 0
	mov numDLL, 0
	mov numDll, 0

	retourDLL2:			;
	inc numDLL			; Compte le nb de DLL en supplément
	invoke Deci2Char, numDLL		;
	invoke lstrcpy, addr Buffer, offset DLL	;
	invoke lstrcat, addr Buffer, addr nombreHChar	;
	invoke GetPrivateProfileString, offset DLL, addr Buffer, addr erreur, addr BufferDLL, sizeof BufferDLL, addr NomFichierDLL
	cmp dword ptr [BufferDLL], ">--<"	;
	jne retourDLL2			;

	mov eax, 080000000h
	.while tour<=eax
		push ebp
		mov eax, tour	; PROGRESS_BARRE
		mov ebx, 100	;
		mul ebx		; eax = 100*tour
		mov ebx, 11	;
		div ebx		;
		invoke SendMessage, hwndProgress, PBM_SETPOS, eax, 0
		inc tour
		.IF tour == 1
			invoke lstrcpy, addr Buffer, addr version
		.ELSEIF tour == 2
			invoke lstrcpy, addr Buffer, addr crtdll
		.ELSEIF tour == 3
			invoke lstrcpy, addr Buffer, addr Shell32
		.ELSEIF tour == 4
			invoke lstrcpy, addr Buffer, addr Gdi
		.ELSEIF tour == 5
			invoke lstrcpy, addr Buffer, addr olesvr
		.ELSEIF tour == 6
			invoke lstrcpy, addr Buffer, addr olecli
		.ELSEIF tour == 7
			invoke lstrcpy, addr Buffer, addr comdlg32
		.ELSEIF tour == 8
			invoke lstrcpy, addr Buffer, addr advapi32
		.ELSEIF tour == 9
			invoke lstrcpy, addr Buffer, addr comctl32
		.ELSEIF tour == 10
			invoke lstrcpy, addr Buffer, addr User32
		.ELSEIF tour == 11
			invoke lstrcpy, addr Buffer, addr Kernel32
		.ELSE
			inc numDll					; Compte le nb de DLL en supplément
			mov eax, numDll				;
			cmp eax, numDLL				;
			je _Exit					;
			invoke Deci2Char, numDll			;
			invoke lstrcpy, addr Buffer, offset DLL		;
			invoke lstrcat, addr Buffer, addr nombreHChar		;
			invoke GetPrivateProfileString, addr DLL, addr Buffer, addr erreur, addr BufferDLL, sizeof BufferDLL, addr NomFichierDLL
			invoke GetPrivateProfileString, addr Buffer, addr BufferDLL,addr erreur, addr buffer, sizeof buffer, addr NomFichierDLL
			invoke lstrcpy, addr Buffer, addr BufferDLL
		.ENDIF

		.if tour<=11
			invoke GetSystemDirectory, addr buffer, sizeof buffer
			invoke lstrcat, addr buffer, addr AntiSlash
			invoke lstrcat, addr buffer, addr Buffer
		.endif

		invoke CreateFile, addr buffer, GENERIC_READ, FILE_SHARE_READ, NULL, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, NULL
		.if eax!=INVALID_HANDLE_VALUE
			mov hFile, eax
			invoke CreateFileMapping, hFile, NULL, PAGE_READONLY,0,0,0
			.if eax!=NULL
				mov hMapping, eax
				invoke MapViewOfFile,hMapping,FILE_MAP_READ,0,0,0
				.if eax!=NULL
					mov pMapping,eax
					assume fs:nothing
					push fs:[0]
					pop seh.PrevLink
					mov seh.CurrentHandler,offset SEHHandler
					mov seh.SafeOffset,offset FinalExitExp
					lea eax,seh
					mov fs:[0], eax
					mov seh.PrevEsp,esp
					mov seh.PrevEbp,ebp
					mov edi, pMapping
					assume edi:ptr IMAGE_DOS_HEADER
					.if [edi].e_magic==IMAGE_DOS_SIGNATURE
						add edi, [edi].e_lfanew
						assume edi:ptr IMAGE_NT_HEADERS
						.if [edi].Signature==IMAGE_NT_SIGNATURE
							mov ValidPE, TRUE
						.else
							mov ValidPE, FALSE
						.endif
					.else
						mov ValidPE,FALSE
					.endif
FinalExitExp:
					push seh.PrevLink
					pop fs:[0]

					.if ValidPE==TRUE
						invoke ShowTheFunctionsExp, edi
					.else
						invoke MessageBox,0, addr FileInValidPE, addr AppName,MB_OK+MB_ICONERROR
					.endif
					invoke UnmapViewOfFile, pMapping
				.else
					invoke MessageBox, 0, addr FileMappingError, addr AppName,MB_OK+MB_ICONERROR
				.endif
				invoke CloseHandle,hMapping
			.else
				invoke MessageBox, 0, addr FileOpenMappingError, addr AppName,MB_OK+MB_ICONERROR
			.endif
			invoke CloseHandle, hFile
		.else
			invoke MessageBox, 0, addr FileOpenError, addr AppName, MB_OK+MB_ICONERROR
		.endif
		pop ebp
		mov eax, tour
		add eax, numDll
	.endw
	_Exit:
	ret
FindExports endp



DlgProcLV2 PROC hWndLV:HWND,iMsg:DWORD,wParam:WPARAM, lParam:LPARAM
LOCAL	rect:RECT
	.if iMsg==WM_INITDIALOG
		invoke CreateWindowEx, NULL, addr ListViewClassName, NULL, LVS_REPORT+WS_CHILD+WS_VISIBLE, 0,0,0,0,hWndLV, NULL, hInstance, NULL
		mov hList, eax
		call InsertColumnExp
		call FindExports
		RGB 255,255,255
		invoke SendMessage,hList,LVM_SETTEXTCOLOR,0,eax
		RGB 155,5,255
		invoke SendMessage,hList,LVM_SETBKCOLOR,0,eax
		RGB 155,5,255
		invoke SendMessage,hList,LVM_SETTEXTBKCOLOR,0,eax
		invoke GetMenu,hWndLV
		mov hMenu,eax
		invoke CheckMenuRadioItem,hMenu,IDM_ICON,IDM_LIST, IDM_REPORT,MF_CHECKED
	.elseif iMsg==WM_CREATE
		invoke GetWindowRect, hwndDlg, addr rect
		mov ecx, rect.right						; ecx =
		sub ecx, rect.left						; Largeur de la fenêtre ListView
		push ecx
		mov ebx, rect.bottom						; ebx =
		sub ebx, rect.top						; Hauteur de la fenêtre ListView
		invoke GetWindowRect, HWNDParent, addr rect
		pop ecx
		invoke MoveWindow, hwndDlg, rect.left,rect.bottom,ecx, ebx, TRUE
	.elseif iMsg==WM_COMMAND
		.if lParam==0
			invoke GetWindowLong,hList,GWL_STYLE
			and eax,not LVS_TYPEMASK
			mov edx,wParam
			and edx,0FFFFh			
			push edx
			or eax,edx
			invoke SetWindowLong,hList,GWL_STYLE,eax
			pop edx
			invoke CheckMenuRadioItem,hMenu,IDM_ICON,IDM_LIST, edx,MF_CHECKED
		.endif
	.elseif iMsg==WM_NOTIFY
		push edi
		mov edi,lParam
		assume edi:ptr NMHDR
		mov eax,[edi].hwndFrom
		.if eax==hList
			.if [edi].code==LVN_COLUMNCLICK
				assume edi:ptr NM_LISTVIEW				
				.if [edi].iSubItem==1
					.if SizeSortOrder==0 || SizeSortOrder==2
						invoke SendMessage,hList,LVM_SORTITEMS,1,offset CompareFunc
						invoke UpdatelParam
						mov SizeSortOrder,1
					.else
						invoke SendMessage,hList,LVM_SORTITEMS,2,offset CompareFunc
						invoke UpdatelParam
						mov SizeSortOrder,2
					.endif					
				.else
					.if FileNameSortOrder==0 || FileNameSortOrder==4
						invoke SendMessage,hList,LVM_SORTITEMS,3,offset CompareFunc
						invoke UpdatelParam
						mov FileNameSortOrder,3
					.else
						invoke SendMessage,hList,LVM_SORTITEMS,4,offset CompareFunc
						invoke UpdatelParam
						mov FileNameSortOrder,4
					.endif										
				.endif
			assume edi:ptr NMHDR
			.elseif [edi].code==NM_DBLCLK
				call AjouterCetteFonction
			.endif
		.endif
		pop edi
	.elseif iMsg==WM_SIZE
		mov eax,lParam
		mov edx,eax
		and eax,0ffffh
		shr edx,16
		invoke MoveWindow,hList, 0, 0, eax,edx,TRUE
	.elseif iMsg==WM_MOVE
		invoke GetWindowRect, hwndDlgLV2, addr rect
		mov ecx, rect.right						; ecx =
		sub ecx, rect.left						; Largeur de la fenêtre ListView
		push ecx
		mov ebx, rect.bottom						; ebx =
		sub ebx, rect.top						; Hauteur de la fenêtre ListView
		invoke GetWindowRect, HWNDParent, addr rect
		pop ecx
		invoke MoveWindow, hwndDlgLV2, rect.left,rect.bottom,ecx, ebx, TRUE
	.elseif iMsg==WM_CLOSE
		invoke EndDialog,hwndDlgLV2,NULL
		mov hwndDlgLV2,0
	.elseif iMsg==WM_DESTROY
		invoke PostQuitMessage,NULL
	.endif
	xor  eax,eax
	ret
DlgProcLV2 endp

AjouterCetteFonction proc 
	LOCAL lvi			:LV_ITEM
	LOCAL bufferNomDLL[30]	:BYTE
	LOCAL  PrevDLL[30]		:BYTE
	LOCAL bufferListView[256]	:BYTE
	LOCAL bufferNomFonc[50]	:BYTE
	LOCAL numDLL		:DWORD
	LOCAL numFonc		:DWORD
	LOCAL NomFichier[100]	:BYTE
	LOCAL buffer0[50]		:BYTE

	jmp data@5
	vouloir	db "Voulez-vous ajouter cette fonction",0Dh, 0Ah
		db "au fichier AddFunc.ini ?", 0Dh, 0Ah
		db " ", 0Dh, 0Ah
		db "(", 0
	vouloirA	db "Do you want to add this function",0Dh, 0Ah
		db "into AddFunc.ini file ?", 0Dh, 0Ah
		db " ", 0Dh, 0Ah
		db "(", 0
	fermer	db ")",0
	Nettoyage	db "Attendez 5 secondes le temps de nettoyer", 0Dh, 0Ah
		db "le fichier d'initialisation...Merci",0
	NettoyageA db "Wait for 5 seconds, the time to clean", 0Dh, 0Ah
		db "the initialization file...Thank You",0
	data@5:

	invoke lstrcpy, addr NomFichier, addr CheminFichier
	invoke lstrcat, addr NomFichier, addr NFichier
	
	.if langage != 40Ch
		invoke lstrcpy, addr bufferListView, addr vouloirA	
	.else
		invoke lstrcpy, addr bufferListView, addr vouloir
	.endif
	invoke SendMessage,hList,LVM_GETNEXTITEM,-1,LVNI_FOCUSED
	mov lvi.iItem,eax
	mov lvi.iSubItem,0
	mov lvi.imask,LVIF_TEXT
	lea eax,bufferNomFonc
	mov lvi.pszText,eax
	mov lvi.cchTextMax,256
	invoke SendMessage,hList,LVM_GETITEM,0,addr lvi
	invoke lstrcat, addr bufferListView, addr bufferNomFonc
	invoke lstrcat, addr bufferListView, addr fermer
	invoke lstrcpy, addr buffer0, addr bufferNomFonc
	;-----------------
	invoke SendMessage,hList,LVM_GETNEXTITEM,-1,LVNI_FOCUSED
	mov lvi.iItem,eax
	mov lvi.iSubItem,1
	mov lvi.imask,LVIF_TEXT
	lea eax, bufferNomDLL
	mov lvi.pszText,eax
	mov lvi.cchTextMax,256
	invoke SendMessage,hList,LVM_GETITEM,0,addr lvi
	invoke lstrcpy, addr PrevDLL, addr bufferNomDLL
	invoke MessageBox, 0, addr bufferListView, addr bufferNomDLL, MB_YESNO
	cmp eax, 6
	jne NePasInscrire
	
		invoke Deci2Char, 1
		invoke lstrcpy, addr Buffer, addr DLL
		invoke lstrcat, addr Buffer, addr nombreHChar
		invoke GetPrivateProfileString, addr DLL, addr Buffer, addr erreur, addr BufferDLL, sizeof BufferDLL, addr NomFichier
		.if dword ptr [BufferDLL] == 05F6D6F4Eh
			invoke DeleteFile, addr NomFichier
			.if langage != 40Ch
				invoke MessageBox, 0, addr NettoyageA, addr AppName, 40h
			.else
				invoke MessageBox, 0, addr Nettoyage, addr AppName, 40h
			.endif
		.endif

		mov numFonc, 0
		mov numDLL, 0
		retourDLL:
			inc numDLL
			invoke Deci2Char, numDLL
			invoke lstrcpy, addr Buffer, addr DLL
			invoke lstrcat, addr Buffer, addr nombreHChar
			invoke GetPrivateProfileString, addr DLL, addr Buffer, addr erreur, addr BufferDLL, sizeof BufferDLL, addr NomFichier
			invoke lstrcpy, addr Buffer, addr BufferDLL
			invoke lcase, addr BufferDLL
			invoke lcase, addr  bufferNomDLL
			invoke lstrcmpi, addr BufferDLL, addr bufferNomDLL
			cmp eax, 0
			jne pasTrouveLaDLL
				mov numFonc, 0
				mov dword ptr [BufferFonction],  0
				retourFonctions:
					inc numFonc
					invoke Deci2Char, numFonc
					invoke lstrcpy, addr buffer, addr F
					invoke lstrcat, addr buffer, addr nombreHChar
					invoke GetPrivateProfileString, addr Buffer, addr buffer, addr erreur, addr BufferFonction, sizeof BufferFonction, addr NomFichier

					invoke lcase, addr BufferFonction
					invoke lcase, addr bufferNomFonc
					invoke lstrcmpi, addr BufferFonction, addr bufferNomFonc
					cmp eax, 0
					je fonctionDejaPresente

					.if  dword ptr [BufferFonction] == ">--<"
						invoke WritePrivateProfileString, addr Buffer, addr buffer, addr buffer0, addr NomFichier
					.endif
					
					;invoke MessageBox, 0, addr Buffer, addr buffer, 0
				cmp dword ptr [BufferFonction], ">--<"
				jne retourFonctions
			pasTrouveLaDLL:
			fonctionDejaPresente:
		cmp dword ptr [BufferDLL], ">--<"
		jne retourDLL
		.if numFonc == 0
			invoke Deci2Char, numDLL
			invoke lstrcpy, addr Buffer, addr DLL
			invoke lstrcat, addr Buffer, addr nombreHChar
			invoke WritePrivateProfileString, addr DLL, addr Buffer, addr  PrevDLL, addr NomFichier	
			inc numFonc
			invoke Deci2Char, numFonc
			invoke lstrcpy, addr Buffer, addr F
			invoke lstrcat, addr Buffer, addr nombreHChar
			invoke WritePrivateProfileString, addr PrevDLL, addr Buffer, addr buffer0 ,addr NomFichier
		.endif
	NePasInscrire:
	ret
AjouterCetteFonction endp